System & Version

unknown · Post by **unknown** » Mar 31, 2007 1:57

Is there a way to retrieve which system is running, (XP, Linux, DOS) and it's version, (specifically windows, 98/XP/Vista)?

Vendan · Post by **Vendan** » Mar 31, 2007 2:23

It's a bit jury rigged, but here

Code: Select all

#ifdef __FB_WIN32__
#include "windows.bi"
#endif
#ifdef __FB_LINUX_
Print "I'm on Linux!"
#endif
#ifdef __FB_DOS__
print "Im on Dos!"
#endif
#ifdef __FB_WIN32__
dim WindowsVersion as OSVERSIONINFO
WindowsVersion.dwOSVersionInfoSize = len(OSVERSIONINFO)
GetVersionEx(@WindowsVersion)
select case WindowsVersion.dwMajorVersion
	case 4
		select case WindowsVersion.dwMinorVersion
			case 0
				if WindowsVersion.dwPlatformId = 2 then
					print "I'm on Windows NT"
				else
					print "I'm on Windows 95
				end if
			case 10
				print "I'm on Windows 98"
			case 90
				print "I'm on Windows ME"
		end select
	case 5
		select case WindowsVersion.dwMinorVersion
			case 0
				print "I'm on Windows 2000"
			case 1
				print "I'm on Windows XP"
			case 2
				print "I'm on Windows 2003, Windows 2003 R2, or Windows XP x64"
		end select
	case 6
		select case WindowsVersion.dwMinorVersion
			case 0
				print "I'm on Windows Vista or Windows Server 'Longhorn'"
		end select
end select
#endif

unknown · Post by **unknown** » Mar 31, 2007 2:30

Thank you, Sir. That example was exactly what I needed.