var a = 1, b = 2
        Print a + b

        A$ = (Integer)1;
        B$ = (Integer)2;
        #define vr$1 ((Integer)(A$ + B$))
        fb_PrintInt( (Integer)0, vr$1, (Integer)1 );

' The Lord of the Julia Rings
' The Fellowship of the Julia Ring
' Free Basic
' Relsoft
' Rel.BetterWebber.com

'#define USE_PTC

#ifdef USE_PTC
  #define PTC_WIN
  #include once "tinyptc.bi"
#endif

Const SCR_WIDTH  = 320
Const SCR_HEIGHT = 240
Const SCR_SIZE = SCR_WIDTH*SCR_HEIGHT
Const SCR_MIDX = SCR_WIDTH  \ 2
Const SCR_MIDY = SCR_HEIGHT \ 2


Const As Single PI = 3.141593
Const MAXITER = 20

Dim Shared As Single Lx(SCR_WIDTH -1)
Dim Shared As Single Ly(SCR_HEIGHT-1)
Dim As Uinteger Ptr pBuffer
Dim Shared As Uinteger Buffer(SCR_SIZE-1)

#ifdef USE_PTC
  If ptc_open( "Julia (Relsoft) TinyPTC", SCR_WIDTH, SCR_HEIGHT ) = 0 Then
    Print "error: ptc_open() !"
    Beep:Sleep:End
  End If
  pBuffer = @Buffer(0)

#else
  screenres SCR_WIDTH,SCR_HEIGHT,32
  If screenptr = 0 Then
    Print "error: screenres !"
    Beep:Sleep:End
  End If
  WindowTitle "Julia (Relsoft) FBGfx"
  pBuffer = ScreenPtr()
#endif

Dim As Uinteger Ptr pTop,pBottom
Dim As Single  xmin, xmax,ymin,ymax
Dim As Single  theta,ty,p,q
Dim As Single  x,y,x2,y2
Dim As Integer px,py,i,i_last,ii
Dim As Integer frames
Dim As Integer red,grn,blu
Dim As Double  sTime,nTime
Dim As Single  cmag,cmag2,zmag,zTot
Dim As Single  drad,drad_L,drad_H

xmin = -2.0:xmax =  2.0
ymin = -1.5:ymax =  1.5

For i = 0 To SCR_WIDTH - 1
  lx(i) = xmin + i * (xmax - xmin) / (SCR_WIDTH  - 1)
Next i

For i = 0 To SCR_HEIGHT - 1
  ly(i) = ymax - i * (ymax - ymin) / (SCR_HEIGHT - 1)
Next i

Sleep 1000,1

' start time
sTime = Timer()
Do
  pTop    = pBuffer
  pBottom = pBuffer + (SCR_SIZE-1)
  frames = (frames + 1) And &H7fffffff
  theta = frames * PI / 180
  p = Cos(theta) * Sin(theta * .7)
  q = Sin(theta) + Sin(theta     )
  p = p * .6
  q = q * .6
  cmag2 = (p*p + q*q)
  cmag = Sqr(cmag2)
 
  drad = 0.04
  drad_L = cmag   - drad
  drad_L = drad_L * drad_L
  drad_H = cmag   + drad
  drad_H = drad_H * drad_H

#ifndef USE_PTC
  ScreenLock
#endif

  For py = 0 To SCR_HEIGHT\2 -1
    ty = ly(py)
    For px = 0 To SCR_WIDTH - 1
      x = Lx(px)
      y = ty
      ztot =0
      i = 0
      While (i < MAXITER)
        x2 = x * x
        y2 = y * y
        zmag = (x2 + y2)
        If zmag > 4.0 Then Exit While
        If (i > 0) Then
          If (zmag > drad_L) Then
            If (zmag < drad_H) Then
              ztot = ztot + ( 1 - (Abs(zmag - cmag2) / drad))
              i_last = i
            End If
          End If
        End If
        i = i + 1
        y = x * y
        y = y + y + q
        x = x2-y2 + p
      Wend
     
      If ztot > 0 Then
        i = Cint(Sqr(ztot) * 500)
        If i>0 Then
          If i<256 Then
            red=i:  i=i * 0.33
            red=(red+i) * 0.33
            grn=     i  * 0.33
            blu=(red+i) * 0.33
          Else
            i-=256
            If i<256 Then
              grn=i:i=(255+i) * 0.33
              red=(255+grn+i) * 0.33
              grn=(grn+    i) * 0.33
              blu=(red+    i) * 0.33
            Else
              i-=256
              If i<256 Then
                blu=i:ii=(510+i) * 0.33
                red=(510+    ii) * 0.33
                grn=(255+i  +ii) * 0.33
                blu=(i  +red+ii) * 0.33
              Else
                red=254 '= (255+255+(255+255+255)*0.33)*0.33
                grn=254 '=      "                 "
                blu=254 '= (255+red+(255+255+255)*0.33)*0.33
              End If
            End If
          End If

          Select Case As Const (i_last And 3)
            Case 1   :*pTop = rgb( grn, blu, red )
            Case 2   :*pTop = rgb( blu, red, grn )
            Case Else:*pTop = rgb( red, grn, blu )
          End Select
          *pBottom=*pTop
        Else
         *pTop   =0
         *pBottom=0
        End If
      Else
        *pTop   =0
        *pBottom=0
      End If
      pTop   +=1
      pBottom-=1
    Next
  Next

  If (frames Mod 100)=0 Then
    If Len(Inkey) Then Exit Do
  End If
  #ifdef USE_PTC
    ptc_update pBuffer
  #else
    screenunlock
  #endif
Loop
' now time
nTime=Timer()

#ifdef USE_PTC
  ptc_close
#endif

Screen 0
' clear key buffer for next sleep
While Len(Inkey):Wend

#ifdef USE_PTC
  Print "TinyPTC benchmark"
#else
  Print "FBGfx   benchmark"
#endif
Print "-----------------------------------"
Print "counted " & frames & " frames total"
Print "frames per seconds = " & frames/(nTime-sTime)
Sleep